forked from BigfootDev/flatbuffers
c1e7aee489
* Migrate from rules_nodejs to rules_js/rules_ts (take 2) This is the second version of patch #7923. The first version got reverted because bazel query was failing: $ bazel --nosystem_rc --nohome_rc query tests(set('//...')) except tests(attr("tags", "manual", set('//...'))) ERROR: Traceback (most recent call last): File "/workdir/tests/ts/bazel_repository_test_dir/BUILD", line 6, column 22, in <toplevel> npm_link_all_packages(name = "node_modules") File "/var/lib/buildkite-agent/.cache/bazel/_bazel_buildkite-agent/ec321eb2cc2d0f8f91b676b6d4c66c29/external/npm/defs.bzl", line 188, column 13, in npm_link_all_packages fail(msg) Error in fail: The npm_link_all_packages() macro loaded from @npm//:defs.bzl and called in bazel package 'tests/ts/bazel_repository_test_dir' may only be called in bazel packages that correspond to the pnpm root package '' and pnpm workspace projects '' This was happening because the `.bazelrc` file only added `--deleted_packages` to the `build` command. We also need it for the `query` command. This second version of the patch fixes that. Original commit message: This patch migrates the current use of rules_nodejs to the new rules_js. rules_js is the intended replacement of rules_nodejs as per this note: https://github.com/aspect-build/rules_js#relationship-to-rules_nodejs > rules_js is an alternative to the build_bazel_rules_nodejs Bazel module > and accompanying npm packages hosted in > https://github.com/bazelbuild/rules_nodejs, which is now > unmaintained. All users are recommended to use rules_js instead. There are a few notable changes in this patch: 1. The `flatbuffer_ts_library` macro no longer accepts a `package_name` attribute. This is because rules_js appears to manage the import naming of dependencies via top-level `npm_link_package` targets. Users will have to migrate. 2. I added a few more arguments to `flatbuffer_library_public()`. These helped with exposing esbuild to `ts/compile_flat_file.sh`. 3. I pinned the version of `typescript` in `package.json` so that rules_ts can download the exact same version. rules_ts doesn't know what to do if the version isn't exact. 4. Since rules_js uses the pnpm locking mechanism, we now have a `pnpm-lock.yaml` file instead of a yarn lock file. 4. I added bazel targets for a few of the existing tests in `tests/ts`. They can be run with `bazel test //test/ts:all`. Since there is no flexbuffers bazel target, I did not add a bazel target for the corresponding test. 5. I added a separate workspace in `tests/ts/bazel_repository_test_dir/` to validate that the flatbuffers code can be imported as an external repository. You can run the test with `bazel test //test/ts:bazel_repository_test`. For this to work, I needed to expose a non-trivial chunk of the flatbuffers code to the test. I achieved this through some recursive `distribution` filegroups. This is inspired by rules_python's workspace tests. I did not do anything special to validate that the `gen_reflections` parameter works the same. This patch doesn't change anything about the TypeScript generation. As a side note: I am not an expert with rules_js. This patch is my attempt based on my limited understanding of the rule set. Fixes #7817 * Fix the query --------- Co-authored-by: Derek Bailey <derekbailey@google.com>
91 lines
3.3 KiB
Python
91 lines
3.3 KiB
Python
"""
|
|
Rules for building typescript flatbuffers with Bazel.
|
|
"""
|
|
|
|
load("@aspect_rules_js//js:defs.bzl", "js_library")
|
|
load(":build_defs.bzl", "flatbuffer_library_public")
|
|
|
|
DEFAULT_FLATC_TS_ARGS = [
|
|
"--gen-object-api",
|
|
"--gen-mutable",
|
|
"--reflect-names",
|
|
"--gen-name-strings",
|
|
"--ts-flat-files",
|
|
"--keep-prefix",
|
|
]
|
|
|
|
def flatbuffer_ts_library(
|
|
name,
|
|
srcs,
|
|
compatible_with = None,
|
|
target_compatible_with = None,
|
|
deps = [],
|
|
include_paths = None,
|
|
flatc_args = DEFAULT_FLATC_TS_ARGS,
|
|
visibility = None,
|
|
restricted_to = None,
|
|
gen_reflections = False):
|
|
"""Generates a ts_library rule for a given flatbuffer definition.
|
|
|
|
Args:
|
|
name: Name of the generated ts_library rule.
|
|
srcs: Source .fbs file(s).
|
|
deps: Other flatbuffer_ts_library's to depend on. Note that currently
|
|
you must specify all your transitive dependencies manually.
|
|
include_paths: Optional, list of paths the includes files can be found in.
|
|
flatc_args: Optional list of additional arguments to pass to flatc
|
|
(e.g. --gen-mutable).
|
|
visibility: The visibility of the generated cc_library. By default, use the
|
|
default visibility of the project.
|
|
compatible_with: Optional, The list of environments this rule can be built
|
|
for, in addition to default-supported environments.
|
|
restricted_to: Optional, The list of environments this rule can be built
|
|
for, instead of default-supported environments.
|
|
target_compatible_with: Optional, The list of target platform constraints
|
|
to use.
|
|
gen_reflections: Optional, if true this will generate the flatbuffer
|
|
reflection binaries for the schemas.
|
|
"""
|
|
srcs_lib = "%s_srcs" % (name)
|
|
out_base = [s.replace(".fbs", "").split("/")[-1].split(":")[-1] for s in srcs]
|
|
|
|
if len(srcs) != 1:
|
|
fail("flatbuffer_ts_library only supports one .fbs file per target currently.")
|
|
|
|
outs = ["%s_generated.cjs" % s for s in out_base]
|
|
includes = [d + "_includes" for d in deps]
|
|
reflection_name = "%s_reflection" % name if gen_reflections else ""
|
|
flatbuffer_library_public(
|
|
name = srcs_lib,
|
|
srcs = srcs,
|
|
outs = outs,
|
|
language_flag = "--ts",
|
|
includes = includes,
|
|
include_paths = include_paths,
|
|
extra_env = "ESBUILD_BIN=$(ESBUILD_BIN)",
|
|
flatc_args = flatc_args + ["--filename-suffix _generated"],
|
|
compatible_with = compatible_with,
|
|
restricted_to = restricted_to,
|
|
reflection_name = reflection_name,
|
|
reflection_visibility = visibility,
|
|
target_compatible_with = target_compatible_with,
|
|
flatc_path = "@com_github_google_flatbuffers//ts:compile_flat_file",
|
|
toolchains = ["@aspect_rules_esbuild//esbuild:resolved_toolchain"],
|
|
tools = ["@aspect_rules_esbuild//esbuild:resolved_toolchain"],
|
|
)
|
|
js_library(
|
|
name = name,
|
|
visibility = visibility,
|
|
compatible_with = compatible_with,
|
|
restricted_to = restricted_to,
|
|
target_compatible_with = target_compatible_with,
|
|
srcs = outs,
|
|
)
|
|
native.filegroup(
|
|
name = "%s_includes" % (name),
|
|
srcs = srcs + includes,
|
|
compatible_with = compatible_with,
|
|
restricted_to = restricted_to,
|
|
visibility = visibility,
|
|
)
|