Migrate from rules_nodejs to rules_js/rules_ts (take 2) (#7928)

* Migrate from rules_nodejs to rules_js/rules_ts (take 2)

This is the second version of patch #7923. The first version got
reverted because bazel query was failing:

    $ bazel --nosystem_rc --nohome_rc query tests(set('//...')) except tests(attr("tags", "manual", set('//...')))
    ERROR: Traceback (most recent call last):
    	File "/workdir/tests/ts/bazel_repository_test_dir/BUILD", line 6, column 22, in <toplevel>
    		npm_link_all_packages(name = "node_modules")
    	File "/var/lib/buildkite-agent/.cache/bazel/_bazel_buildkite-agent/ec321eb2cc2d0f8f91b676b6d4c66c29/external/npm/defs.bzl", line 188, column 13, in npm_link_all_packages
    		fail(msg)
    Error in fail: The npm_link_all_packages() macro loaded from @npm//:defs.bzl and called in bazel package 'tests/ts/bazel_repository_test_dir' may only be called in bazel packages that correspond to the pnpm root package '' and pnpm workspace projects ''

This was happening because the `.bazelrc` file only added
`--deleted_packages` to the `build` command. We also need it for the
`query` command. This second version of the patch fixes that.

Original commit message:

This patch migrates the current use of rules_nodejs to the new rules_js.
rules_js is the intended replacement of rules_nodejs as per this note:
https://github.com/aspect-build/rules_js#relationship-to-rules_nodejs

> rules_js is an alternative to the build_bazel_rules_nodejs Bazel module
> and accompanying npm packages hosted in
> https://github.com/bazelbuild/rules_nodejs, which is now
> unmaintained. All users are recommended to use rules_js instead.

There are a few notable changes in this patch:
1. The `flatbuffer_ts_library` macro no longer accepts a `package_name`
   attribute. This is because rules_js appears to manage the import
   naming of dependencies via top-level `npm_link_package` targets.
   Users will have to migrate.
2. I added a few more arguments to `flatbuffer_library_public()`. These
   helped with exposing esbuild to `ts/compile_flat_file.sh`.
3. I pinned the version of `typescript` in `package.json` so that
   rules_ts can download the exact same version. rules_ts doesn't know
   what to do if the version isn't exact.
4. Since rules_js uses the pnpm locking mechanism, we now have a
   `pnpm-lock.yaml` file instead of a yarn lock file.
4. I added bazel targets for a few of the existing tests in `tests/ts`.
   They can be run with `bazel test //test/ts:all`. Since there is no
   flexbuffers bazel target, I did not add a bazel target for the
   corresponding test.
5. I added a separate workspace in `tests/ts/bazel_repository_test_dir/`
   to validate that the flatbuffers code can be imported as an external
   repository. You can run the test with
   `bazel test //test/ts:bazel_repository_test`. For this to work, I
   needed to expose a non-trivial chunk of the flatbuffers code to the
   test. I achieved this through some recursive `distribution`
   filegroups. This is inspired by rules_python's workspace tests.

I did not do anything special to validate that the `gen_reflections`
parameter works the same. This patch doesn't change anything about
the TypeScript generation.

As a side note: I am not an expert with rules_js. This patch is my
attempt based on my limited understanding of the rule set.

Fixes #7817

* Fix the query

---------

Co-authored-by: Derek Bailey <derekbailey@google.com>

.bazelignore

@@ -0,0 +1 @@
+node_modules

.bazelrc

@@ -0,0 +1,4 @@
+# We cannot use "common" here because the "version" command doesn't support
+# --deleted_packages. We need to specify it for both build and query instead.
+build --deleted_packages=tests/ts/bazel_repository_test_dir
+query --deleted_packages=tests/ts/bazel_repository_test_dir

.npmrc

@@ -0,0 +1 @@
+hoist=false

BUILD.bazel

@@ -1,3 +1,5 @@
+load("@aspect_rules_js//npm:defs.bzl", "npm_link_package")
+load("@npm//:defs.bzl", "npm_link_all_packages")
 load("@rules_cc//cc:defs.bzl", "cc_binary", "cc_library")
 
 licenses(["notice"])
@@ -6,6 +8,13 @@ package(
     default_visibility = ["//visibility:public"],
 )
 
+npm_link_all_packages(name = "node_modules")
+
+npm_link_package(
+    name = "node_modules/flatbuffers",
+    src = "//ts:flatbuffers",
+)
+
 exports_files([
     "LICENSE",
     "tsconfig.json",
@@ -25,6 +34,23 @@ config_setting(
     ],
 )
 
+filegroup(
+    name = "distribution",
+    srcs = [
+        "BUILD.bazel",
+        "WORKSPACE",
+        "build_defs.bzl",
+        "typescript.bzl",
+        "//grpc/src/compiler:distribution",
+        "//reflection:distribution",
+        "//src:distribution",
+        "//ts:distribution",
+    ] + glob([
+        "include/flatbuffers/*.h",
+    ]),
+    visibility = ["//visibility:public"],
+)
+
 # Public flatc library to compile flatbuffer files at runtime.
 cc_library(
     name = "flatbuffers",

WORKSPACE

@@ -1,6 +1,6 @@
 workspace(name = "com_github_google_flatbuffers")
 
-load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
+load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive", "http_file")
 
 http_archive(
     name = "platforms",
@@ -76,30 +76,80 @@ load("@com_github_grpc_grpc//bazel:grpc_extra_deps.bzl", "grpc_extra_deps")
 grpc_extra_deps()
 
 # rules_go from https://github.com/bazelbuild/rules_go/releases/tag/v0.34.0
+
 http_archive(
-    name = "build_bazel_rules_nodejs",
+    name = "aspect_rules_js",
-    sha256 = "965ee2492a2b087cf9e0f2ca472aeaf1be2eb650e0cfbddf514b9a7d3ea4b02a",
+    sha256 = "124ed29fb0b3d0cba5b44f8f8e07897cf61b34e35e33b1f83d1a943dfd91b193",
-    urls = ["https://github.com/bazelbuild/rules_nodejs/releases/download/5.2.0/rules_nodejs-5.2.0.tar.gz"],
+    strip_prefix = "rules_js-1.24.0",
+    url = "https://github.com/aspect-build/rules_js/releases/download/v1.24.0/rules_js-v1.24.0.tar.gz",
 )
 
-load("@build_bazel_rules_nodejs//:repositories.bzl", "build_bazel_rules_nodejs_dependencies")
+load("@aspect_rules_js//js:repositories.bzl", "rules_js_dependencies")
 
-build_bazel_rules_nodejs_dependencies()
+rules_js_dependencies()
 
-load("@build_bazel_rules_nodejs//:index.bzl", "node_repositories", "yarn_install")
+load("@aspect_rules_js//npm:npm_import.bzl", "npm_translate_lock", "pnpm_repository")
 
-node_repositories()
+pnpm_repository(name = "pnpm")
 
-yarn_install(
+http_archive(
+    name = "aspect_rules_ts",
+    sha256 = "8eb25d1fdafc0836f5778d33fb8eaac37c64176481d67872b54b0a05de5be5c0",
+    strip_prefix = "rules_ts-1.3.3",
+    url = "https://github.com/aspect-build/rules_ts/releases/download/v1.3.3/rules_ts-v1.3.3.tar.gz",
+)
+
+load("@aspect_rules_ts//ts:repositories.bzl", "rules_ts_dependencies")
+
+rules_ts_dependencies(
+    # Since rules_ts doesn't always have the newest integrity hashes, we
+    # compute it manually here.
+    #   $ curl --silent https://registry.npmjs.org/typescript/5.0.4 | jq ._integrity
+    ts_integrity = "sha512-cW9T5W9xY37cc+jfEnaUvX91foxtHkza3Nw3wkoF4sSlKn0MONdkdEndig/qPBWXNkmplh3NzayQzCiHM4/hqw==",
+    ts_version_from = "//:package.json",
+)
+
+load("@rules_nodejs//nodejs:repositories.bzl", "DEFAULT_NODE_VERSION", "nodejs_register_toolchains")
+
+nodejs_register_toolchains(
+    name = "nodejs",
+    node_version = DEFAULT_NODE_VERSION,
+)
+
+npm_translate_lock(
     name = "npm",
-    exports_directories_only = False,
+    npmrc = "//:.npmrc",
-    # Unfreeze to add/remove packages.
+    pnpm_lock = "//:pnpm-lock.yaml",
-    frozen_lockfile = False,
+    # Set this to True when the lock file needs to be updated, commit the
-    package_json = "//:package.json",
+    # changes, then set to False again.
-    symlink_node_modules = False,
+    update_pnpm_lock = False,
-    yarn_lock = "//:yarn.lock",
+    verify_node_modules_ignored = "//:.bazelignore",
 )
 
-load("@build_bazel_rules_nodejs//toolchains/esbuild:esbuild_repositories.bzl", "esbuild_repositories")
+load("@npm//:repositories.bzl", "npm_repositories")
 
-esbuild_repositories(npm_repository = "npm")
+npm_repositories()
+
+http_archive(
+    name = "aspect_rules_esbuild",
+    sha256 = "2ea31bd97181a315e048be693ddc2815fddda0f3a12ca7b7cc6e91e80f31bac7",
+    strip_prefix = "rules_esbuild-0.14.4",
+    url = "https://github.com/aspect-build/rules_esbuild/releases/download/v0.14.4/rules_esbuild-v0.14.4.tar.gz",
+)
+
+# Register a toolchain containing esbuild npm package and native bindings
+load("@aspect_rules_esbuild//esbuild:repositories.bzl", "LATEST_VERSION", "esbuild_register_toolchains")
+
+esbuild_register_toolchains(
+    name = "esbuild",
+    esbuild_version = LATEST_VERSION,
+)
+
+http_file(
+    name = "bazel_linux_x86_64",
+    downloaded_file_path = "bazel",
+    sha256 = "e89747d63443e225b140d7d37ded952dacea73aaed896bca01ccd745827c6289",
+    urls = [
+        "https://github.com/bazelbuild/bazel/releases/download/6.1.2/bazel-6.1.2-linux-x86_64",
+    ],
+)

build_defs.bzl

@@ -48,7 +48,10 @@ def flatbuffer_library_public(
         restricted_to = None,
         target_compatible_with = None,
         flatc_path = "@com_github_google_flatbuffers//:flatc",
-        output_to_bindir = False):
+        output_to_bindir = False,
+        tools = None,
+        extra_env = None,
+        **kwargs):
     """Generates code files for reading/writing the given flatbuffers in the requested language using the public compiler.
 
     Args:
@@ -73,6 +76,11 @@ def flatbuffer_library_public(
         to use.
       flatc_path: Bazel target corresponding to the flatc compiler to use.
       output_to_bindir: Passed to genrule for output to bin directory.
+      tools: Optional, passed to genrule for list of tools to make available
+        during the action.
+      extra_env: Optional, must be a string of "VAR1=VAL1 VAR2=VAL2". These get
+        set as environment variables that "flatc_path" sees.
+      **kwargs: Passed to the underlying genrule.
 
 
     This rule creates a filegroup(name) with all generated source files, and
@@ -83,6 +91,8 @@ def flatbuffer_library_public(
         include_paths = default_include_paths(flatc_path)
     include_paths_cmd = ["-I %s" % (s) for s in include_paths]
 
+    extra_env = extra_env or ""
+
     # '$(@D)' when given a single source target will give the appropriate
     # directory. Appending 'out_prefix' is only necessary when given a build
     # target with multiple sources.
@@ -92,7 +102,7 @@ def flatbuffer_library_public(
     genrule_cmd = " ".join([
         "SRCS=($(SRCS));",
         "for f in $${SRCS[@]:0:%s}; do" % len(srcs),
-        "OUTPUT_FILE=\"$(OUTS)\" $(location %s)" % (flatc_path),
+        "OUTPUT_FILE=\"$(OUTS)\" %s $(location %s)" % (extra_env, flatc_path),
         " ".join(include_paths_cmd),
         " ".join(flatc_args),
         language_flag,
@@ -105,12 +115,13 @@ def flatbuffer_library_public(
         srcs = srcs + includes,
         outs = outs,
         output_to_bindir = output_to_bindir,
-        tools = [flatc_path],
+        tools = (tools or []) + [flatc_path],
         cmd = genrule_cmd,
         compatible_with = compatible_with,
         target_compatible_with = target_compatible_with,
         restricted_to = restricted_to,
         message = "Generating flatbuffer files for %s:" % (name),
+        **kwargs
     )
     if reflection_name:
         reflection_genrule_cmd = " ".join([

grpc/src/compiler/BUILD.bazel

@@ -4,6 +4,16 @@ package(
     default_visibility = ["//visibility:public"],
 )
 
+filegroup(
+    name = "distribution",
+    srcs = [
+        "BUILD.bazel",
+    ] + glob([
+        "*.cc",
+        "*.h",
+    ]),
+)
+
 filegroup(
     name = "common_headers",
     srcs = [

package.json

@@ -36,12 +36,11 @@
   "homepage": "https://google.github.io/flatbuffers/",
   "dependencies": {},
   "devDependencies": {
-    "@bazel/typescript": "5.2.0",
     "@types/node": "18.15.11",
     "@typescript-eslint/eslint-plugin": "^5.57.0",
     "@typescript-eslint/parser": "^5.57.0",
     "esbuild": "^0.17.14",
     "eslint": "^8.37.0",
-    "typescript": "^5.0.3"
+    "typescript": "5.0.4"
   }
 }

reflection/BUILD.bazel

@@ -1,3 +1,12 @@
+filegroup(
+    name = "distribution",
+    srcs = [
+        "BUILD.bazel",
+        "reflection.fbs",
+    ],
+    visibility = ["//visibility:public"],
+)
+
 filegroup(
     name = "reflection_fbs_schema",
     srcs = ["reflection.fbs"],

reflection/ts/BUILD.bazel

@@ -9,7 +9,6 @@ genrule(
 
 flatbuffer_ts_library(
     name = "reflection_ts_fbs",
-    package_name = "flatbuffers_reflection",
     srcs = [":reflection.fbs"],
     visibility = ["//visibility:public"],
 )

src/BUILD.bazel

@@ -5,6 +5,17 @@ package(
     default_visibility = ["//visibility:private"],
 )
 
+filegroup(
+    name = "distribution",
+    srcs = [
+        "BUILD.bazel",
+    ] + glob([
+        "*.cpp",
+        "*.h",
+    ]),
+    visibility = ["//visibility:public"],
+)
+
 cc_library(
     name = "code_generators",
     srcs = ["code_generators.cpp"],

tests/BUILD.bazel

@@ -1,8 +1,20 @@
+load("@aspect_bazel_lib//lib:copy_to_bin.bzl", "copy_to_bin")
 load("@rules_cc//cc:defs.bzl", "cc_test")
 load("//:build_defs.bzl", "flatbuffer_cc_library")
 
 package(default_visibility = ["//visibility:private"])
 
+# rules_js works around various JS tooling limitations by copying everything
+# into the output directory. Make the test data available to the tests this way.
+copy_to_bin(
+    name = "test_data_copied_to_bin",
+    srcs = glob([
+        "*.mon",
+        "*.json",
+    ]),
+    visibility = ["//tests/ts:__subpackages__"],
+)
+
 # Test binary.
 cc_test(
     name = "flatbuffers_test",

tests/ts/BUILD.bazel

@@ -1,3 +1,4 @@
+load("@aspect_rules_js//js:defs.bzl", "js_test")
 load("//:typescript.bzl", "flatbuffer_ts_library")
 
 package(default_visibility = ["//visibility:private"])
@@ -10,3 +11,68 @@ flatbuffer_ts_library(
         "//tests/ts/test_dir:typescript_transitive_ts_fbs",
     ],
 )
+
+TEST_DATA = glob([
+    "my-game/*.js",
+    "my-game/example/*.js",
+    "my-game/example2/*.js",
+])
+
+TEST_UNION_VECTOR_DATA = glob([
+    "union_vector/*.js",
+])
+
+TEST_COMPLEX_ARRAYS_DATA = glob([
+    "arrays_test_complex/**/*.js",
+])
+
+# Here we're running the tests against the checked-in generated files. These
+# are kept up-to-date with a CI-based mechanism. The intent of running these
+# tests here via bazel is not to validate that they're up-to-date. Instead, we
+# just want to make it easy to run these tests while making other changes. For
+# example, this is useful when making changes to the rules_js setup to validate
+# that the basic infrastructure is still working.
+[js_test(
+    name = "%s_test" % test,
+    chdir = package_name(),
+    data = data + [
+        "package.json",
+        "//:node_modules/flatbuffers",
+        "//tests:test_data_copied_to_bin",
+    ],
+    entry_point = "%s.js" % test,
+) for test, data in (
+    ("JavaScriptTest", TEST_DATA),
+    ("JavaScriptUnionVectorTest", TEST_UNION_VECTOR_DATA),
+    # TODO(philsc): Figure out how to run this test with flexbuffers available.
+    # At the moment the flexbuffer library is not exposed as a bazel target.
+    #("JavaScriptFlexBuffersTest", TBD_DATA)
+    ("JavaScriptComplexArraysTest", TEST_COMPLEX_ARRAYS_DATA),
+)]
+
+sh_test(
+    name = "bazel_repository_test",
+    srcs = ["bazel_repository_test.sh"],
+    data = [
+        "//:distribution",
+        "@bazel_linux_x86_64//file",
+    ] + glob(
+        [
+            "bazel_repository_test_dir/**/*",
+        ],
+        exclude = [
+            "bazel_repository_test_dir/bazel-*/**",
+        ],
+    ),
+    tags = [
+        # Since we have bazel downloading external repositories inside this
+        # test, we need to give it access to the internet.
+        "requires-network",
+    ],
+    # We only have x86_64 Linux bazel exposed so restrict the test to that.
+    target_compatible_with = [
+        "@platforms//cpu:x86_64",
+        "@platforms//os:linux",
+    ],
+    deps = ["@bazel_tools//tools/bash/runfiles"],
+)

tests/ts/bazel_repository_test.sh

@@ -0,0 +1,29 @@
+#!/bin/bash
+
+# This test makes sure that a separate repository can import the flatbuffers
+# repository and use it in their JavaScript code.
+
+# --- begin runfiles.bash initialization v3 ---
+# Copy-pasted from the Bazel Bash runfiles library v3.
+set -uo pipefail; set +e; f=bazel_tools/tools/bash/runfiles/runfiles.bash
+source "${RUNFILES_DIR:-/dev/null}/$f" 2>/dev/null || \
+  source "$(grep -sm1 "^$f " "${RUNFILES_MANIFEST_FILE:-/dev/null}" | cut -f2- -d' ')" 2>/dev/null || \
+  source "$0.runfiles/$f" 2>/dev/null || \
+  source "$(grep -sm1 "^$f " "$0.runfiles_manifest" | cut -f2- -d' ')" 2>/dev/null || \
+  source "$(grep -sm1 "^$f " "$0.exe.runfiles_manifest" | cut -f2- -d' ')" 2>/dev/null || \
+  { echo>&2 "ERROR: cannot find $f"; exit 1; }; f=; set -e
+# --- end runfiles.bash initialization v3 ---
+
+BAZEL_BIN="$(rlocation bazel_linux_x86_64/file/bazel)"
+readonly BAZEL_BIN
+
+if [[ ! -e "${BAZEL_BIN}" ]]; then
+    echo "Failed to find the bazel binary." >&2
+    exit 1
+fi
+
+export PATH="$(dirname "${BAZEL_BIN}"):${PATH}"
+
+cd tests/ts/bazel_repository_test_dir/
+
+bazel test //...

tests/ts/bazel_repository_test_dir/.bazelignore

@@ -0,0 +1 @@
+node_modules

tests/ts/bazel_repository_test_dir/.bazelrc

@@ -0,0 +1 @@
+build --symlink_prefix=/

tests/ts/bazel_repository_test_dir/.gitignore

@@ -0,0 +1 @@
+bazel-*

tests/ts/bazel_repository_test_dir/.npmrc

@@ -0,0 +1 @@
+../../../.npmrc

tests/ts/bazel_repository_test_dir/BUILD

@@ -0,0 +1,32 @@
+load("@aspect_rules_js//js:defs.bzl", "js_test")
+load("@com_github_google_flatbuffers//:typescript.bzl", "flatbuffer_ts_library")
+load("@aspect_rules_js//npm:defs.bzl", "npm_link_package")
+load("@npm//:defs.bzl", "npm_link_all_packages")
+
+npm_link_all_packages(name = "node_modules")
+
+npm_link_package(
+    name = "node_modules/flatbuffers",
+    src = "@com_github_google_flatbuffers//ts:flatbuffers",
+)
+
+flatbuffer_ts_library(
+    name = "one_fbs",
+    srcs = ["one.fbs"],
+)
+
+flatbuffer_ts_library(
+    name = "two_fbs",
+    srcs = ["two.fbs"],
+    deps = [":one_fbs"],
+)
+
+js_test(
+    name = "import_test",
+    data = [
+        "package.json",
+        ":node_modules/flatbuffers",
+        ":two_fbs",
+    ],
+    entry_point = "import_test.js",
+)

tests/ts/bazel_repository_test_dir/WORKSPACE

@@ -0,0 +1,71 @@
+workspace(name = "bazel_repository_test")
+
+load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
+
+local_repository(
+    name = "com_github_google_flatbuffers",
+    path = "../../../",
+)
+
+http_archive(
+    name = "aspect_rules_js",
+    sha256 = "124ed29fb0b3d0cba5b44f8f8e07897cf61b34e35e33b1f83d1a943dfd91b193",
+    strip_prefix = "rules_js-1.24.0",
+    url = "https://github.com/aspect-build/rules_js/releases/download/v1.24.0/rules_js-v1.24.0.tar.gz",
+)
+
+load("@aspect_rules_js//js:repositories.bzl", "rules_js_dependencies")
+
+rules_js_dependencies()
+
+load("@aspect_rules_js//npm:npm_import.bzl", "npm_translate_lock", "pnpm_repository")
+
+pnpm_repository(name = "pnpm")
+
+http_archive(
+    name = "aspect_rules_ts",
+    sha256 = "8eb25d1fdafc0836f5778d33fb8eaac37c64176481d67872b54b0a05de5be5c0",
+    strip_prefix = "rules_ts-1.3.3",
+    url = "https://github.com/aspect-build/rules_ts/releases/download/v1.3.3/rules_ts-v1.3.3.tar.gz",
+)
+
+load("@aspect_rules_ts//ts:repositories.bzl", "rules_ts_dependencies")
+
+rules_ts_dependencies(
+    # curl --silent https://registry.npmjs.org/typescript/5.0.3 | jq ._integrity
+    ts_integrity = "sha512-xv8mOEDnigb/tN9PSMTwSEqAnUvkoXMQlicOb0IUVDBSQCgBSaAAROUZYy2IcUy5qU6XajK5jjjO7TMWqBTKZA==",
+    ts_version = "5.0.3",
+)
+
+load("@rules_nodejs//nodejs:repositories.bzl", "DEFAULT_NODE_VERSION", "nodejs_register_toolchains")
+
+nodejs_register_toolchains(
+    name = "nodejs",
+    node_version = DEFAULT_NODE_VERSION,
+)
+
+npm_translate_lock(
+    name = "npm",
+    npmrc = "//:.npmrc",
+    pnpm_lock = "//:pnpm-lock.yaml",
+    verify_node_modules_ignored = "//:.bazelignore",
+)
+
+load("@npm//:repositories.bzl", "npm_repositories")
+
+npm_repositories()
+
+http_archive(
+    name = "aspect_rules_esbuild",
+    sha256 = "2ea31bd97181a315e048be693ddc2815fddda0f3a12ca7b7cc6e91e80f31bac7",
+    strip_prefix = "rules_esbuild-0.14.4",
+    url = "https://github.com/aspect-build/rules_esbuild/releases/download/v0.14.4/rules_esbuild-v0.14.4.tar.gz",
+)
+
+# Register a toolchain containing esbuild npm package and native bindings
+load("@aspect_rules_esbuild//esbuild:repositories.bzl", "LATEST_VERSION", "esbuild_register_toolchains")
+
+esbuild_register_toolchains(
+    name = "esbuild",
+    esbuild_version = LATEST_VERSION,
+)

tests/ts/bazel_repository_test_dir/import_test.js

@@ -0,0 +1,28 @@
+import assert from 'assert'
+import * as flatbuffers from 'flatbuffers'
+
+import two_cjs from './two_generated.cjs'
+
+const bazel_repository_test = two_cjs.bazel_repository_test;
+
+function main() {
+  // Validate building a table with a table field.
+  var fbb = new flatbuffers.Builder(1);
+
+  bazel_repository_test.One.startOne(fbb);
+  bazel_repository_test.One.addInformation(fbb, 42);
+  var one = bazel_repository_test.One.endOne(fbb);
+
+  bazel_repository_test.Two.startTwo(fbb);
+  bazel_repository_test.Two.addOne(fbb, one);
+  var two = bazel_repository_test.Two.endTwo(fbb);
+
+  fbb.finish(two);
+
+  // Call as a sanity check. Would be better to validate actual output here.
+  fbb.asUint8Array();
+
+  console.log('FlatBuffers bazel repository test: completed successfully');
+}
+
+main();

tests/ts/bazel_repository_test_dir/one.fbs

@@ -0,0 +1,7 @@
+namespace bazel_repository_test;
+
+table One {
+  information:int;
+}
+
+root_type One;

tests/ts/bazel_repository_test_dir/package.json

@@ -0,0 +1,8 @@
+{
+  "name": "bazel_repository_test",
+  "type": "module",
+  "private": true,
+  "devDependencies": {
+    "@types/node": "18.15.11"
+  }
+}

tests/ts/bazel_repository_test_dir/pnpm-lock.yaml

@@ -0,0 +1,12 @@
+lockfileVersion: '6.0'
+
+devDependencies:
+  '@types/node':
+    specifier: 18.15.11
+    version: 18.15.11
+
+packages:
+
+  /@types/node@18.15.11:
+    resolution: {integrity: sha512-E5Kwq2n4SbMzQOn6wnmBjuK9ouqlURrcZDVfbo9ftDDTFt3nk7ZKK4GMOzoYgnpQJKcxwQw+lGaBvvlMo0qN/Q==}
+    dev: true

tests/ts/bazel_repository_test_dir/two.fbs

@@ -0,0 +1,9 @@
+include 'one.fbs';
+
+namespace bazel_repository_test;
+
+table Two {
+  one:One;
+}
+
+root_type Two;

tests/ts/package.json

@@ -1,7 +1,6 @@
 {
     "type": "module",
     "dependencies": {
-        "@grpc/grpc-js": "^1.7.0",
         "flatbuffers": "../../"
     }
 }

tests/ts/test_dir/BUILD.bazel

@@ -1,3 +1,4 @@
+load("@aspect_rules_js//js:defs.bzl", "js_test")
 load("//:typescript.bzl", "flatbuffer_ts_library")
 
 flatbuffer_ts_library(
@@ -12,3 +13,14 @@ flatbuffer_ts_library(
     visibility = ["//visibility:public"],
     deps = [":typescript_transitive_ts_fbs"],
 )
+
+js_test(
+    name = "import_test",
+    chdir = package_name(),
+    data = [
+        "package.json",
+        ":include_ts_fbs",
+        "//:node_modules/flatbuffers",
+    ],
+    entry_point = "import_test.js",
+)

tests/ts/test_dir/import_test.js

@@ -0,0 +1,31 @@
+import assert from 'assert'
+import * as flatbuffers from 'flatbuffers'
+
+import typescript_include from './typescript_include_generated.cjs'
+
+const foobar = typescript_include.foobar;
+
+function main() {
+  // Validate the enums.
+  assert.strictEqual(foobar.Abc.a, 0);
+  assert.strictEqual(foobar.class_.arguments_, 0);
+
+  // Validate building a table.
+  var fbb = new flatbuffers.Builder(1);
+  var name = fbb.createString("Foo Bar");
+
+  foobar.Tab.startTab(fbb);
+  foobar.Tab.addAbc(fbb, foobar.Abc.a);
+  foobar.Tab.addArg(fbb, foobar.class_.arguments_);
+  foobar.Tab.addName(fbb, name);
+  var tab = foobar.Tab.endTab(fbb);
+
+  fbb.finish(tab);
+
+  // Call as a sanity check. Would be better to validate actual output here.
+  fbb.asUint8Array();
+
+  console.log('FlatBuffers Bazel Import test: completed successfully');
+}
+
+main();

tests/ts/test_dir/package.json

@@ -0,0 +1,6 @@
+{
+    "type": "module",
+    "dependencies": {
+        "flatbuffers": "../../../"
+    }
+}

tests/ts/test_dir/typescript_include.fbs

@@ -1,6 +1,13 @@
 include 'typescript_transitive_include.fbs';
+
 namespace foobar;
 
 enum class: int {
   arguments,
 }
+
+table Tab {
+  abc:Abc;
+  arg:class;
+  name:string;
+}

ts/BUILD.bazel

@@ -1,5 +1,23 @@
-load("@npm//@bazel/typescript:index.bzl", "ts_project")
+load("@aspect_rules_ts//ts:defs.bzl", "ts_project")
-load("@build_bazel_rules_nodejs//:index.bzl", "js_library")
+load("@aspect_rules_js//npm:defs.bzl", "npm_package")
+
+filegroup(
+    name = "distribution",
+    srcs = [
+        "BUILD.bazel",
+        "compile_flat_file.sh",
+    ] + glob([
+        "*.ts",
+    ]),
+    visibility = ["//visibility:public"],
+)
+
+# Add an index to emulate the top-level package.json's "main" entry.
+genrule(
+    name = "generate_index.ts",
+    outs = ["index.ts"],
+    cmd = """echo "export * from './flatbuffers.js'" > $(OUTS)""",
+)
 
 ts_project(
     name = "flatbuffers_ts",
@@ -11,6 +29,7 @@ ts_project(
         "flatbuffers.ts",
         "types.ts",
         "utils.ts",
+        ":index.ts",
     ],
     declaration = True,
     tsconfig = {
@@ -28,14 +47,19 @@ ts_project(
         },
     },
     visibility = ["//visibility:public"],
-    deps = ["@npm//@types/node"],
+    deps = [
+        # Because the main repository instantiates the @npm repository, we need
+        # to depend on the main repository's node import.
+        "@//:node_modules/@types/node",
+    ],
 )
 
-js_library(
+npm_package(
     name = "flatbuffers",
-    package_name = "flatbuffers",
+    srcs = [":flatbuffers_ts"],
+    include_external_repositories = ["*"],
+    package = "flatbuffers",
     visibility = ["//visibility:public"],
-    deps = [":flatbuffers_ts"],
 )
 
 sh_binary(
@@ -44,7 +68,6 @@ sh_binary(
     data = [
         "@com_github_google_flatbuffers//:flatc",
         "@nodejs_linux_amd64//:node_bin",
-        "@npm//esbuild/bin:esbuild",
     ],
     # We just depend directly on the linux amd64 nodejs binary, so only support
     # running this script on amd64 for now.

ts/compile_flat_file.sh

@@ -14,10 +14,9 @@ source "${RUNFILES_DIR:-/dev/null}/$f" 2>/dev/null || \
   source "$(grep -sm1 "^$f " "$0.exe.runfiles_manifest" | cut -f2- -d' ')" 2>/dev/null || \
   { echo>&2 "ERROR: cannot find $f"; exit 1; }; f=; set -e
 # --- end runfiles.bash initialization v2 ---
-set -e
+set -eu
 runfiles_export_envvars
 FLATC=$(rlocation com_github_google_flatbuffers/flatc)
-ESBUILD=$(rlocation npm/node_modules/esbuild/bin/esbuild)
 TS_FILE=$(${FLATC}  $@  | grep  "Entry point.*generated" | grep -o "bazel-out.*ts")
-export PATH=$(rlocation nodejs_linux_amd64/bin/nodejs/bin)
+export PATH="$(rlocation nodejs_linux_amd64/bin/nodejs/bin):${PATH}"
-${ESBUILD} ${TS_FILE} --format=cjs --bundle --outfile="${OUTPUT_FILE}"  --external:flatbuffers --log-level=warning
+${ESBUILD_BIN} ${TS_FILE} --format=cjs --bundle --outfile="${OUTPUT_FILE}"  --external:flatbuffers --log-level=warning

typescript.bzl

@@ -2,7 +2,7 @@
 Rules for building typescript flatbuffers with Bazel.
 """
 
-load("@build_bazel_rules_nodejs//:index.bzl", "js_library")
+load("@aspect_rules_js//js:defs.bzl", "js_library")
 load(":build_defs.bzl", "flatbuffer_library_public")
 
 DEFAULT_FLATC_TS_ARGS = [
@@ -24,8 +24,7 @@ def flatbuffer_ts_library(
         flatc_args = DEFAULT_FLATC_TS_ARGS,
         visibility = None,
         restricted_to = None,
-        gen_reflections = False,
+        gen_reflections = False):
-        package_name = None):
     """Generates a ts_library rule for a given flatbuffer definition.
 
     Args:
@@ -46,7 +45,6 @@ def flatbuffer_ts_library(
         to use.
       gen_reflections: Optional, if true this will generate the flatbuffer
         reflection binaries for the schemas.
-      package_name: Optional, Package name to use for the generated code.
     """
     srcs_lib = "%s_srcs" % (name)
     out_base = [s.replace(".fbs", "").split("/")[-1].split(":")[-1] for s in srcs]
@@ -64,6 +62,7 @@ def flatbuffer_ts_library(
         language_flag = "--ts",
         includes = includes,
         include_paths = include_paths,
+        extra_env = "ESBUILD_BIN=$(ESBUILD_BIN)",
         flatc_args = flatc_args + ["--filename-suffix _generated"],
         compatible_with = compatible_with,
         restricted_to = restricted_to,
@@ -71,6 +70,8 @@ def flatbuffer_ts_library(
         reflection_visibility = visibility,
         target_compatible_with = target_compatible_with,
         flatc_path = "@com_github_google_flatbuffers//ts:compile_flat_file",
+        toolchains = ["@aspect_rules_esbuild//esbuild:resolved_toolchain"],
+        tools = ["@aspect_rules_esbuild//esbuild:resolved_toolchain"],
     )
     js_library(
         name = name,
@@ -79,7 +80,6 @@ def flatbuffer_ts_library(
         restricted_to = restricted_to,
         target_compatible_with = target_compatible_with,
         srcs = outs,
-        package_name = package_name,
     )
     native.filegroup(
         name = "%s_includes" % (name),