Initial commit

CMake/Bin2CPPTargets.cmake

@@ -0,0 +1,23 @@
+if(NOT TARGET Bin2CPP)
+    if(CMAKE_CROSSCOMPILING)
+        find_program(BIN2CPP_EXECUTABLE
+            NAMES Bin2CPP
+            PATHS ENV PATH
+            NO_DEFAULT_PATH
+        )
+    else()
+        find_program(BIN2CPP_EXECUTABLE
+            NAMES Bin2CPP
+            PATHS "${CMAKE_CURRENT_LIST_DIR}"
+            NO_DEFAULT_PATH
+        )
+    endif()
+
+    if(BIN2CPP_EXECUTABLE)
+        get_filename_component(BIN2CPP_EXECUTABLE "${BIN2CPP_EXECUTABLE}" ABSOLUTE)
+        add_executable(Bin2CPP IMPORTED)
+        set_property(TARGET Bin2CPP PROPERTY IMPORTED_LOCATION ${BIN2CPP_EXECUTABLE})
+    else()
+        message(WARNING "Bin2CPP executable not found in ${CMAKE_CURRENT_LIST_DIR}")
+    endif()
+endif()

CMake/CustomTargets.cmake

@@ -0,0 +1,19 @@
+add_library(Bin2CPPCompileAndLinkFlags INTERFACE)
+
+target_compile_options(Bin2CPPCompileAndLinkFlags INTERFACE
+        $<$<CXX_COMPILER_ID:MSVC>:/W4 /WX>
+        $<$<CXX_COMPILER_ID:Clang,GNU>:-Wall -Wextra -Wpedantic -Werror>
+        $<$<AND:$<BOOL:${COVERAGE}>,$<CXX_COMPILER_ID:Clang>>:-fprofile-instr-generate -fcoverage-mapping>
+)
+
+target_link_options(Bin2CPPCompileAndLinkFlags INTERFACE
+        $<$<AND:$<BOOL:${COVERAGE}>,$<CXX_COMPILER_ID:Clang>>:-fprofile-instr-generate>
+)
+
+target_compile_definitions(Bin2CPPCompileAndLinkFlags INTERFACE
+        $<$<CONFIG:Release>:BIN2CPP_OPTIMIZED>
+        $<$<CONFIG:Debug,RelWithDebInfo>:BIN2CPP_NOT_OPTIMIZED>
+        $<$<PLATFORM_ID:Windows>:BIN2CPP_WINDOWS>
+        $<$<PLATFORM_ID:Linux>:BIN2CPP_LINUX>
+        $<$<PLATFORM_ID:Windows>:NOMINMAX>
+        $<$<PLATFORM_ID:Windows>:WIN32_LEAN_AND_MEAN>)

CMake/FindDependencies.cmake

@@ -0,0 +1,14 @@
+find_package(Python3 COMPONENTS Interpreter Development)
+
+if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
+    set(THREADS_PREFER_PTHREAD_FLAG ON)
+    find_package(Threads REQUIRED)
+endif()
+
+find_package(magic_enum REQUIRED)
+find_package(CLI11 REQUIRED)
+find_package(quill REQUIRED)
+
+if(BUILD_TESTS)
+    find_package(GTest REQUIRED)
+endif()