get_filename_component(PackageName ${CMAKE_CURRENT_SOURCE_DIR} NAME)
project(${PackageName})

add_executable(${PROJECT_NAME})
target_compile_features(${PROJECT_NAME} PRIVATE cxx_std_20)

file(GLOB_RECURSE BIN2CPPEXE_SOURCES
        CONFIGURE_DEPENDS
        ${CMAKE_CURRENT_SOURCE_DIR}/*.cpp
)

file(GLOB_RECURSE BIN2CPPEXE_HEADERS
        CONFIGURE_DEPENDS
        ${CMAKE_CURRENT_SOURCE_DIR}/*.h
        ${CMAKE_CURRENT_SOURCE_DIR}/*.hpp
)

target_sources(${PROJECT_NAME}
    PRIVATE
        ${BIN2CPPEXE_SOURCES}
    PRIVATE
        FILE_SET HEADERS
        BASE_DIRS
            ${CMAKE_CURRENT_SOURCE_DIR}/Include
        FILES
            ${BIN2CPPEXE_HEADERS}
)

target_link_libraries(${PROJECT_NAME}
    PRIVATE
        Bin2CPPCompileAndLinkFlags
        Bin2CPPLib
        CLI11::CLI11
        ${CMAKE_DL_LIBS})

source_group(TREE ${CMAKE_CURRENT_SOURCE_DIR} PREFIX Src FILES ${BIN2CPPEXE_SOURCES} ${BIN2CPPEXE_HEADERS})

set_target_properties(${PROJECT_NAME} PROPERTIES FOLDER Bin2CPP/${ParentFolder})

##################ASAN SETUP###################

if(${ASAN})
    if(MSVC)
        get_filename_component(MSVC_BIN_DIR "${CMAKE_CXX_COMPILER}" DIRECTORY)
        set(ASAN_DLL "${MSVC_BIN_DIR}/clang_rt.asan_dynamic-x86_64.dll")

        add_custom_command(
            OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}-asan.timestamp"
            DEPENDS "${ASAN_DLL}"
            COMMAND ${CMAKE_COMMAND} -E copy_if_different "${ASAN_DLL}" "$<TARGET_FILE_DIR:${PROJECT_NAME}>"
            COMMAND ${CMAKE_COMMAND} -E touch "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}-asan.timestamp"
            COMMENT "Copying ASan DLL for ${PROJECT_NAME}"
        )

        add_custom_target(${PROJECT_NAME}Asan
            DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}-asan.timestamp"
        )

        add_dependencies(${PROJECT_NAME} ${PROJECT_NAME}Asan)
        set_target_properties(${PROJECT_NAME}Asan PROPERTIES FOLDER UtilityTargets/Bin2CPP/${ParentFolder})
    endif()
endif()

########INSTALL

install(TARGETS ${PROJECT_NAME} DESTINATION bin)